Edna & Harvey: Harvey's New Eyes - vbin

[ghylard]

Game: http://store.steampowered.com/app/219910/

[swuforce]

Try the quickbms scripts. Use both on the ogg file. Don't delete the NULL from end of string.
Export

Code: Select all

goto 8
get name basename
string name += .dat
get size long
get zsize long
clog name 16 zsize size
open FDSE name
log MEMORY_FILE 0 0
get name basename
string name += .txt
set end 0
do
findloc offset string "\xff\xff\xff\xff\x04\x00\x00\x00" 0 ""
if offset == ""
cleanexit
endif
math offset -= 8
goto offset
get var1 long
get var2 long
if var1 != var2
getdstring d 8
else
getdstring d 8
get size long
savepos pos
get check byte
get check2 byte
get check3 byte
get check4 byte
if check = 0x00 ||  check = 0xff || check2 = 0x00 || check2 = 0xff
elseif check3 != 0x00 &&  check3 != 0xff && check4 != 0x00 && check4 != 0xff
set end 1
endif
endif
while end == 0
findloc offset string "\xb5\x4a\x05\x06" 0 "" 0
math offset += 4
goto offset
get files long
for i = 1 to files
get size long
getdstring string size
getdstring dummy 12
get number long
for n = 1 to number
get size long
getdstring string size
get size2 long
getdstring dummy size2
get dummy long
if size > 0 && n = 2
putdstring string size MEMORY_FILE
put 0x0a0d short MEMORY_FILE
endif
next n
next i
get size asize MEMORY_FILE
log name 0 size MEMORY_FILE

Import

Code: Select all

log MEMORY_FILE3 0 8
get name basename
get name2 filename
string name += .dat
open FDSE name
get name basename
string name += .txt
open FDSE name 1
log MEMORY_FILE 0 0
get asize asize
set offset1 0
set end 0
do
findloc offset2 string "\xff\xff\xff\xff\x04\x00\x00\x00" 0 ""
if offset2 == ""
cleanexit
endif
math offset2 -= 8
goto offset2
get var1 long
get var2 long
if var1 != var2
getdstring d 8
else
getdstring d 8
get size long
savepos pos
get check byte
get check2 byte
get check3 byte
get check4 byte
if check = 0x00 ||  check = 0xff || check2 = 0x00 || check2 = 0xff
elseif check3 != 0x00 &&  check3 != 0xff && check4 != 0x00 && check4 != 0xff
set end 1
endif
endif
while end == 0
findloc offset2 string "\xb5\x4a\x05\x06" 0 "" 0
math offset2 += 4
goto offset2
get files long
for i = 1 to files
get size long
getdstring string size
getdstring dummy 12
get number long
for n = 1 to number
savepos offset2
get size long
getdstring string size
if size > 0 && n = 2
xmath dsize "offset2 - offset1"
append
log MEMORY_FILE offset1 dsize
append
get msize asize MEMORY_FILE
goto msize MEMORY_FILE
getct string string 0x00 1
get ad short 1
strlen len string
math len += 1
put len long MEMORY_FILE
putdstring string len MEMORY_FILE
savepos offset1
get size2 long
getdstring dummy size2
get dummy long
else
get size2 long
getdstring dummy size2
get dummy long
endif
next n
next i
xmath dsize "asize - offset1"
append
log MEMORY_FILE offset1 dsize
append
get size asize MEMORY_FILE
comtype zlib_compress
clog MEMORY_FILE2 0 size size MEMORY_FILE
get zsize asize MEMORY_FILE2
goto 8 MEMORY_FILE3
put size long MEMORY_FILE3
put zsize long MEMORY_FILE3
append
log MEMORY_FILE3 0 zsize MEMORY_FILE2
append
get size asize MEMORY_FILE3
log name2 0 size MEMORY_FILE3

[ghylard]

Thanks a lot swuforce, I'm finally going to be able to end the translation of this game begun with the old cxml file.

[aluigi]

For all the languages just remove " && n = 2" from both the scripts