Nanodiver (PSP) pa.arc

[SnowHaze]

Filecutter script outputs these two files after running pa.arc through it:
https://www.dropbox.com/s/plnbwxy7pjl5s2q/pa.arc_0_487266080?dl=1
https://www.dropbox.com/s/55i5ebmcpif4ewv/pa.arc_485168928_487266080?dl=1

pa.arc is about 464MB.
There's also pa.bin, a much smaller file, about 152KB.
https://www.dropbox.com/s/oiyrpqk9klvwscl/pa.bin?dl=1
I hope someone can help me with this, thanks regardless.

[Ekey]

Here we go. Let me know if there are problems.

Code: Select all

# Nanodiver (PSP) (ARC format) 0.1a
# Written by Ekey (h4x0r)
# 
# script for QuickBMS http://quickbms.aluigi.org

open FDDE BIN 0
open FDDE ARC 1

idstring "PAA\0" 0
get NULL long 0
get FILES long 0
get DUMMY long 0
get TOFFSET long 0

goto 0x20 0
for i = 0 < FILES
    get NAMEOFF long 0
    get SIZE long 0
    get DUMMY1 long 0
    get DUMMY2 long 0
    savepos TEMP 0
    goto NAMEOFF 0
    getdstring NAME 32 0
    goto TEMP 0
    putarray 0 i NAME
    putarray 1 i SIZE
next i

goto TOFFSET
for i = 0 < FILES
    get OFFSET long 0
    putarray 2 i OFFSET
next i

for i = 0 < FILES
    getarray NAME 0 i
    getarray SIZE 1 i
    getarray OFFSET 2 i
   
    set EXT extension NAME
    if EXT == "XSB"
        comtype gzip
        clog NAME OFFSET SIZE SIZE 1
    else
        log NAME OFFSET SIZE 1
    endif
next i

[SnowHaze]

It worked perfectly, thanks.