PS2_GAME:Rozen Maiden - Gebetgarten (Japan)and contents of strange iso files

[Parasite]

When extracting the .iso file for the PS2 game Rose Maiden - Gebetgarten, some files are shown but the total size of the extracted files is around 15MB, whereas the ISO is 2 GB. I was able to extract the audio files using 'PS2 SOUND'. I would like to extract the video files stored in this .iso file, but if anyone knows, I would appreciate a response.

[Parasite]

a.png

a.png

https://mega.nz/file/L51QBJDa#Wqu95GgVkUuC0EASPdOuIKxx83gbL4CfCipcgRYJvj4

[BloodRaynare]

The files are not referenced in the ISO filesystem and accessed by it's LBA directly which stored inside two places: The game's executable (SLPM_667.12) for graphics, and FMV (video) cutscenes, and one of the game's IRX modules (TSNDDRVM.IRX) for the audio stuff such as BGMs or SFX/voices. Here's the BMS script to extract all the files:

rozen_maiden_gebetgarten.bms

Code: Select all

open FDSE SLPM_667.12 1

math TOC = 0x1274D8
goto TOC 1

for i = 0
	get UNK long 1
	if UNK != 0x430000 && UNK != 0
		break
	endif
	get OFFSET long 1
	get SIZE long 1
	get ZERO long 1
	string NAME p "DATA1\%05d." i
	if UNK != 0
		math OFFSET * 0x800
		log NAME OFFSET SIZE
	endif
next i

open FDSE TSNDDRVM.IRX 1

math TOC = 0xA500
goto TOC 1

for i = 0
	get OFFSET long 1
	if OFFSET == 0x20000
		break
	endif
	get SIZE long 1
	string NAME p "DATA2\%05d." i
	math OFFSET * 0x800
	log NAME OFFSET SIZE
next i

To use the script, you have to place both of SLPM_667.12 and TSNDDRVM.IRX in the same directory as the ISO file. You can find both of the files inside the ISO. Then point the BMS script to the ISO like this:

Code: Select all

quickbms rozen_maiden_gebetgarten.bms "Rozen Maiden - Gebetgarten (Japan).iso"

Or the GUI way (Just run the quickBMS.exe directly):
1. Select rozen_maiden_gebetgarten.bms script
2. Select the ISO file
3. Select the same directory as the ISO file for the output directory

Also, one more thing. The ISO might weighs at 2GB, but all the data is actually only 1.34 GB or more. The reason is it was padded with dummy sectors so the console could read the datas better.