Namco Museum: 50th Anniversary - NAMCO50.VOL

[phantaton]

Uses a very similar format as the archive mentioned here https://zenhax.com/viewtopic.php?t=1272 but the script provided in the thread outputs incorrect data and errors out when I try to use it on this one.

[BloodRaynare]

Here's a script to extract your variant of the VOL file

Code: Select all

## Namco Museum 50th Anniversary (PS2) - NAMCO50.VOL
## Script by BloodRaynare
## For use with QuickBMS: http://aluigi.altervista.org/quickbms.htm

idstring "PVOL"
get UNK long
get FILES long
get DATASTART long
for i = 0 < FILES 
   get OFFSET long
   get SIZE long
   get FID long
   putarray 0 i OFFSET
   putarray 1 i SIZE
next i

savepos CURRPOSNAME
get REAL_FILES long

for i = 0 < REAL_FILES
   get NAME_OFF long
   math NAME_OFF + CURRPOSNAME
   savepos CURRPOS
   goto NAME_OFF
   get NAME string
   putarray 2 i NAME
   goto CURRPOS
next i

sortarray 3 0

math TMP = 34

for i = 0 < FILES
   getarray OFFSET 0 i
   getarray SIZE   1 i
   if i >= 42
      getarray NAME   2 TMP
      math TMP + 1
   elif i >= 34
      getarray NAME   2 33
   else
      getarray NAME   2 i
   endif
   log NAME OFFSET SIZE
next i

Quite hacky, but it should work.
The problem is the format is a bit weird. The filecount is 44, but the filename entries is only 36. Also, the reason why the extracted files is incorrect is because the files were in certain orders (That's why sortarray is used).
There's a duplicate entries for vssver.scc (If QuickBMS says the file exists, you can either rename it automatically or just overwrite it). It's likely that the VOL has a directory structure or something, which explains the duplicate entries.

[phantaton]

Worked like a charm. Thanks!